class_name Piece
extends MeshInstance3D

const BALL = preload("res://piece/ball.tscn")
const FLOOR_ICE = preload("res://piece/floor_ice.tscn")
const GOAL = preload("res://piece/goal.tscn")
const PLAYER = preload("res://piece/player.tscn")
const WALL = preload("res://piece/wall.tscn")

enum Type {
	Wall,
	Goal,
	Ball,
	Player,
	FloorIce,
}

## squares per second
@export_range(0.1, 50) var anim_speed_normal := 10.0
@export_range(0.1, 50) var anim_speed_slow := 1.0

var tweens: Array[Tween] = []

func anim_speed() -> float:
	return anim_speed_slow if Input.is_action_pressed("slowmo") else anim_speed_normal

func anim_time() -> float:
	return 1/anim_speed()

#TODO: {un,}do_bump animation method (good visual clarity)

func pos_of_lpos(pos: Vector2i, y := 0.0) -> Vector3:
	return Vector3(pos.x, y, pos.y)

func target_pos() -> Vector3:
	return pos_of_lpos(lpos, position.y) + Vector3(0.5, 0, 0.5)

func tween_to_target(tween := create_tween()):
	tween.tween_property(self, "position", target_pos(), anim_time())
	tweens.push_back(tween)

func lpos_of_pos(pos: Vector3) -> Vector2i:
	return Vector2i(int(pos.x), int(pos.z))

## logical position
@onready var lpos := lpos_of_pos(position)

## logical velocity
@export var lvel := Vector2i.ZERO
var lvel_displayed := lvel

@export var type: Piece.Type

var speedometer: Label3D
@onready var arrow := get_node_or_null("Arrow") as MeshInstance3D

# TODO: much, *much* better animation is needed. ESPECIALLY if we're doing slowmo
# (we're doing slowmo because it is SICK)
func do_step(board: Board):
	var move := lvel.clampi(-1, 1)
	var new_pos := lpos + move
	# ball being collided *with* gets the remainder of the momentum
	# EMERGENT COMPLEXITY!??!?
	if board.solid_at(new_pos):
		do_bump(move, lvel).call()
		var ball_here := board.type_at(new_pos, Piece.Type.Ball)
		if ball_here:
			var rem := lvel % 2
			ball_here.do_push(lvel/2 + rem).call()
			lvel = -lvel/2
		else:
			lvel *= -1
		return
	lpos = new_pos
	var on_ice := !!board.type_at(lpos, Piece.Type.FloorIce)
	if not on_ice:
		lvel -= move
		lvel_displayed = lvel
	tween_to_target()

func undo_step() -> Callable:
	var old_pos := lpos
	var old_vel := lvel
	return func():
		lpos = old_pos
		lvel = old_vel
		lvel_displayed = lvel
		tween_to_target()

func do_move(move: Vector2i) -> Callable:
	return func():
		for tween in tweens:
			tween.kill()
		position = target_pos()
		lpos += move
		tween_to_target()

func undo_move() -> Callable:
	var old_pos := lpos
	return func():
		for tween in tweens:
			tween.kill()
		position = target_pos()
		lpos = old_pos
		tween_to_target()

func do_push(move: Vector2i) -> Callable:
	return func():
		lvel += move
		lvel_displayed = lvel

func undo_push() -> Callable:
	var old_vel := lvel
	return func():
		lvel = old_vel
		lvel_displayed = lvel

# no logical effect, purely for aesthetics
# (and communicating !!!! player yes)
func do_bump(move: Vector2i, old_lvel := lvel) -> Callable:
	return func():
		lvel_displayed = old_lvel
		var tween := create_tween()
		tween.tween_property(self, "position", target_pos() + pos_of_lpos(move)/2, anim_time())
		tween.tween_callback(func(): lvel_displayed = lvel)
		tween_to_target(tween)
		tweens.push_back(tween)

# TODO?: maybe fix? maybe the bump should be more complicated?
func undo_bump(move: Vector2i) -> Callable:
	return do_bump(move)

func _ready() -> void:
	speedometer = Label3D.new()
	speedometer.billboard = BaseMaterial3D.BILLBOARD_ENABLED
	speedometer.no_depth_test = true
	speedometer.font_size = 64
	add_child(speedometer)

func format_vel(vel: Vector2) -> String:
	if vel.is_zero_approx():
		return ""
	else:
		# we use abs because the arrow already indicates direction
		return "%d,%d" % [abs(vel.x),abs(vel.y)]

func _process(_delta: float) -> void:
	speedometer.text = format_vel(lvel_displayed)
	if arrow:
		arrow.visible = lvel_displayed != Vector2i.ZERO
	rotation.y = (1.0*lvel_displayed.clampi(-1,1)).angle_to(Vector2.UP)